home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / src / exampleCode / irix / scripts / setup < prev    next >
Encoding:
Text File  |  1994-08-02  |  15.7 KB  |  489 lines
  1. #
  2. # $Id: setup,v 1.32 1994/02/22 21:53:27 carlson Exp carlson $
  3. #
  4. # setup        Called by .login and .cshrc
  5. #
  6. # Synopsis:
  7. #    if ( -e setup ) then
  8. #        set { login | cshrc }
  9. #        source setup
  10. #        unset { login | cshrc }
  11. #    endif
  12. #
  13. # Description:
  14. #    This file is to be used as an extension of the standard .cshrc
  15. #    and .login.  This way, if this file doesn't exist, the
  16. #    standard .cshrc and .login will still work in a basic manner.
  17. #
  18. #    By default, 'setup' does some basic initializing and setting
  19. #    of environment variables.  If the variable $login exists, does
  20. #    functions specific to .login.  If the variable $cshrc exists,
  21. #    does functions specific to .cshrc.
  22. #
  23. # Local csh Variables Defined:
  24. #    ansiterm    Set to one of the following:
  25. #            0    Not an interactive session
  26. #            1    Not an ANSI compatible terminal
  27. #            2    iris-ansi compatible terminal
  28. #            3    vt100 terminal
  29. #    home_host    Set to the machine which is my home.  If the
  30. #            machine which is being set up is NOT my home,
  31. #            then I don't do some things.
  32. #
  33. # Permanent csh Variables Defined:
  34. #    path        Set to the search path for executables.
  35. #    prompt        Set to a fancy prompt string.
  36. #    history        Set to the number of history lines to keep.
  37. #    cdpath        Set to the directories to search for
  38. #            subdirectories when doing a 'cd' command.
  39. #    filec        Set to allow file completion.
  40. #    fignore        Set to those extensions to ignore on file
  41. #            completion.
  42. #    ignoreeof    Set to ignore the ^D end of file to logout.
  43. #    notify        Set to notify when subprocesses complete.
  44. #
  45. # Environment Variables Defined:
  46. #    OS        Defined to the current version of the
  47. #            operating system and the alpha release version.
  48. #    DISPLAY        Set to the local display or, if running
  49. #            remotely, to the remote display.
  50. #    EMACSLOADPATH    Where EMACS looks for .el files.
  51. #    WINEDITOR    The editor Workspace defaults to.
  52. #    CONSOLE        TRUE if this is the console window.
  53. #            Otherwise, not set so we set it here to FALSE.
  54. #    LPDEST        Where enscript sends print files.
  55. #
  56. # Revision History:
  57. #    $Log: setup,v $
  58. # Revision 1.32  1994/02/22  21:53:27  carlson
  59. # Added checking of flag to know when we are in an Emacs subshell.
  60. # Added check to see if we are actually a terminal session or just a subshell.
  61. # Always define WINEDITOR.
  62. # Changed colors of prompt.
  63. #
  64. # Revision 1.31  1993/12/16  22:53:48  carlson
  65. # Changed my home host to heaven.
  66. #
  67. # Revision 1.30  1993/12/16  14:49:22  carlson
  68. # Modified so we don't check the hostname to find out if this is a
  69. #   dialback connection.  Use the user (which should be UNKNOWN).
  70. #
  71. # Revision 1.29  93/08/18  17:12:21  carlson
  72. # Modified the terminal type to use when coming from dial-up to be vt100.
  73. # Added some documentation on how the DISPLAY variable is set.
  74. # Do the same for both calling from dialback and using a vt100.
  75. # Handle special case when logging in from an HP terminal.
  76. # Add $HOME/app-defaults to search path for X defaults.
  77. # Replace checks for $prompt with checks to my variable $ansiterm.
  78. # Added aliases for rcp and xv.
  79. # 
  80. # Revision 1.28  93/06/02  10:59:36  carlson
  81. # Modify to keep version in a file identified by each host.  This way,
  82. #   I can NFS mount my home directory, if I want.
  83. # Changed prompt to have the expanded hostname rather than compute it
  84. #   each time.
  85. # Modified aliases that fix the title of the window to use expanded
  86. #   hostname rather than compute it each time.
  87. # Moved all the special stuff for opening windows to .sgisession.
  88. # 
  89. # Revision 1.27  93/03/29  09:31:39  carlson
  90. # Only run unique on path if it exists.
  91. # Added cu alias to clean up after using.
  92. # Only run zmail if it exists.
  93. # Only run status e-lisp function if it exists.
  94. # 
  95. # Revision 1.19  1993/03/27  04:52:14  chris
  96. # Added alias for cu so that it fixes the title bar.
  97. # Added neatsy keansy stuff for epoch when it first loads.
  98. #
  99. # Revision 1.18  1993/02/15  01:05:00  chris
  100. # Modified to be more machine independent.
  101. # Modified mailbox to better know where we are.
  102. #
  103. # Revision 1.25  93/01/22  12:27:01  carlson
  104. # Modified check for LPDEST to make sure we are running on an IRIX
  105. #   system first.
  106. # Modified calls to run mailbox to have better Lat/Long values and to
  107. #   run the mail programs under xwsh.
  108. # 
  109. # Revision 1.24  93/01/06  17:42:30  carlson
  110. # Modified EMACSLOADPATH to use the new format.
  111. # 
  112. # Revision 1.23  92/10/29  13:30:12  carlson
  113. # Added backup (bu) alias.
  114. # 
  115. # Revision 1.22  92/10/27  10:10:44  carlson
  116. # Do not make anything dependent on $OS being defined.
  117. # Use 'unique' program to remove duplicate entries in path variable.
  118. # Added xlock alias.
  119. # Make sure labugs user exists before creating the mailbox for them.
  120. # Disable bell from mailbox program (since zmail does it for me).
  121. # 
  122. # Revision 1.21  92/10/07  14:39:18  carlson
  123. # No longer check if OS is defined for a number of things.  It didn't
  124. #   work as expected.
  125. # Move the definition of OS to the end of the common script.
  126. # Use command unique instead of using a script to remove duplicate
  127. #   directories from the path statement.
  128. # Change where zmail is positioned.
  129. # Remove position information from calls to epoch.
  130. # 
  131. # Revision 1.20  92/08/28  17:13:26  carlson
  132. # Use the variable OS to determine if we need to do things.  This way we
  133. #   don't duplicate efforts.
  134. # Found a faster way to clear away duplicate entries in path.
  135. # Remove alias for make to pmake.
  136. # Define aliases for seticon and settitle in appropriate place.
  137. # Remove size info for epoch.
  138. # 
  139. # Revision 1.19  92/08/28  11:18:31  carlson
  140. # Fixed EXPLORERHOME to be /usr relative.
  141. # Changed default mail handler for mailbox back to BSD mail.
  142. # Automatically load zmail.
  143. # Don't include size information when loading epoch.
  144. # 
  145. # Revision 1.18  92/08/21  15:30:01  carlson
  146. # Added environment variable XENVIRONMENT if .Xdefaults_xxx is defined.
  147. # 
  148. # Revision 1.17  92/08/21  12:57:09  carlson
  149. # Skip a whole bunch of stuff if ENVONLY is defined.  This makes the program
  150. #   userenv (which is called in .xsession) work.
  151. # Change EXPLORERHOME to be /usr relative instead of in /d1.
  152. # 
  153. # Revision 1.16  92/08/19  16:42:42  carlson
  154. # Fixed path to find things in /usr rather than on /d1.
  155. # Added wp to path.
  156. # 
  157. # Revision 1.15  92/08/11  16:48:43  carlson
  158. # If remote host is dialback, then assume iris-ansi-net terminal device.
  159. # Create the .version file if it doesn't exist or it is zero in length.  For
  160. #   some reason, there are times when it gets cleared.
  161. # If the remote host is dialback, remove the DISPLAY environment variable.
  162. #   Otherwise, set the display variable to point to the remote host.
  163. # If the DISPLAY environment variable is set, define emacs, epoch and
  164. #   zmail to use them.  Otherwise, make emacs use the terminal device and
  165. #   don't allow epoch to run.
  166. # Remove stuff that came from Jack's .cshrc a long time ago.
  167. # 
  168. # Revision 1.14  92/03/18  16:14:02  carlson
  169. # Unset clobber - was set by desktop group in /etc/cshrc.
  170. # Added aliases for epoch and zmail.
  171. # Removed running of emacs by default.
  172. # Changed running of mailbox to use zmail, not Mail.
  173. # If epoch exists, run epoch else run emacs on status file.
  174. # If not home machine just run epoch or emacs.
  175. # 
  176. # Revision 1.13  92/01/22  15:23:39  carlson
  177. # Added environment EXPLORERHOME.
  178. # Broke up search path to be divided into two.  Those that are to be
  179. #   searched first and those that are searched last.  This improves the
  180. #   way it works when changing to root.
  181. # Added Framemaker and Explorer to the search path.
  182. # Clean up search path to remove anything already there.
  183. # 
  184. # Revision 1.12  91/10/10  16:12:45  carlson
  185. # Modified netemacs alias to pass parameters in the right place.
  186. # 
  187. # Revision 1.11  91/09/06  13:34:12  carlson
  188. # Removed alias of domcs when on home machine.
  189. # 
  190. # Revision 1.10  91/09/06  12:33:33  carlson
  191. # Modified RCS Header symbol to Id symbol.
  192. # Added netemacs alias.
  193. # 
  194. # Revision 1.9  91/08/27  15:20:37  carlson
  195. # Have the status EMACS start in directory misc.  This way it will load
  196. # the .emacsrc file.
  197. # 
  198. # Revision 1.8  91/08/27  13:12:44  carlson
  199. # Added alias for ci.
  200. # 
  201. # Revision 1.7  91/08/27  12:41:17  carlson
  202. # Modified definition of OS to allow no .version file.
  203. # Include search for FrameMaker directory.
  204. # Set notify only if not console window.
  205. # 
  206. # Revision 1.6  91/08/13  13:10:31  carlson
  207. # Modified call to run emacs editing status to have special instance name.
  208. # 
  209. # Revision 1.5  91/08/13  12:00:44  carlson
  210. # Added RCS special symbols.
  211. # Improved documentation in title block.
  212. # Added emacs alias to handle new X version of emacs.
  213. # Start two emacs windows, one for standard use, one for status.
  214. # 
  215. #-------------------------------------------------------------------------
  216.  
  217. set home_host = heaven
  218. set hostname = `hostname`
  219.  
  220. if ( $?REMOTEHOST ) then
  221.     if ( "$REMOTEUSER" == "UNKNOWN" ) then
  222.     setenv TERM vt100
  223.     endif
  224. endif
  225.  
  226. if ( ! $?ENVONLY ) then
  227.     set ansiterm = 0
  228.     if ( $?prompt && ! $?INEMACS ) then
  229.     set ansiterm = 1
  230.     if ( -t 0 ) then
  231.         if ( "$TERM" == "iris-ansi" || "$TERM" == "iris-ansi-net" ) \
  232.         set ansiterm = 2
  233.         if ( "$TERM" == "vt100" ) set ansiterm = 3
  234.     endif
  235.     endif
  236. endif
  237.  
  238. #-----
  239. # Required by X Windows
  240. #
  241. # Set the DISPLAY environment variable.
  242. #    1. If remote host is dialback, then we are logging in from home
  243. #       and we aren't using X.  Remove the DISPLAY environment variable.
  244. #    2. If there is no prompt, then we are using 'rcp' and we don't
  245. #       need to worry about a DISPLAY environment variable.
  246. #    3. If the 'hosts' file lists only the IP address and the hostname,
  247. #       then we must be at PDA and need to use the IP address instead
  248. #       of the hostname provided.
  249. #    4. Set XUSERFILESEARCHPATH so that app-defaults files will be used
  250. #       properly.
  251. #    5. If we are not logging in remotely, just set DISPLAY to the
  252. #       local screen.
  253. #
  254. if ( $?REMOTEHOST ) then
  255.     if ( "$REMOTEUSER" == "UNKNOWN" || $ansiterm != 2 ) then
  256.     if ( $?DISPLAY ) unsetenv DISPLAY
  257.     else if ( $ansiterm > 0 ) then
  258.     set ip = `ypmatch $REMOTEHOST hosts`
  259.     if ( $#ip == 2 ) then
  260.         setenv DISPLAY $ip[1]\:0
  261.     else
  262.         setenv DISPLAY $REMOTEHOST\:0
  263.     endif
  264.     unset ip
  265.     setenv XUSERFILESEARCHPATH "$HOME/app-defaults/%N:`/usr/bin/X11/appdefpath`"
  266.     endif
  267. else
  268.     setenv DISPLAY :0
  269. endif
  270.  
  271. #-----
  272. # Set other environment variables.
  273. #
  274. if ( ! $?EMACSLOADPATH ) setenv EMACSLOADPATH    ~/emacs:
  275. if ( ! $?ENVONLY ) then
  276.     setenv WINEDITOR        /usr/local/bin/emacs
  277.     if ( ! $?CONSOLE ) \
  278.     setenv CONSOLE        false
  279.     set x = `uname`
  280.     if ( "$x" == "IRIX" ) then
  281.     if ( ! $?LPDEST ) then
  282.         set x = ( `lpstat -d` )
  283.         if ( "$x[1]" != "no" ) setenv LPDEST    $x[4]
  284.     endif
  285.     endif
  286.     unset x
  287.     if ( ! $?EXPLORERHOME && -e /usr/explorer/bin ) \
  288.     setenv EXPLORERHOME    /usr/explorer
  289. endif
  290.  
  291. if ( $?XSCREEN ) then
  292.     if ( "$XSCREEN" == "1280x1024" && -r $HOME/.Xdefaults_1280 ) then
  293.     setenv XENVIRONMENT $HOME/.Xdefaults_1280
  294.     else if ( "$XSCREEN" == "1024x768" && -r $HOME/.Xdefaults_1024 ) then
  295.     setenv XENVIRONMENT $HOME/.Xdefaults_1024
  296.     endif
  297. endif
  298.  
  299. #-----
  300. # Set the search path.
  301. #
  302. # dir1    Directories to search first.
  303. # dir2    Directories to search last.
  304. #
  305. set dir1
  306. if ( -e ~/bin )        set dir1 = ( $dir1 ~/bin )
  307. if ( -e ~/scripts )        set dir1 = ( $dir1 ~/scripts )
  308. if ( -e /usr/local/bin )    set dir1 = ( $dir1 /usr/local/bin )
  309.  
  310. set dir2
  311. if ( -e /usr/frame/bin )    set dir2 = ( $dir2 /usr/frame/bin )
  312. if ( -e /usr/explorer/bin )    set dir2 = ( $dir2 /usr/explorer/bin )
  313. if ( -e /usr/wp/bin )    set dir2 = ( $dir2 /usr/wp/bin /usr/wp/sbin )
  314.  
  315. if ( -o /bin/su ) then
  316.     set path = ( $path $dir1 $dir2 )
  317. else
  318.     set path = ( . $dir1 $path $dir2 )
  319. endif
  320.  
  321. if ( -e ~/bin/unique ) set path = ( `unique $path` )
  322.  
  323. unset dir1
  324. unset dir2
  325.  
  326. #-----
  327. # Make an environment variable that tells us what release of the
  328. # operating system we are running.  Note that we create a file called
  329. # .version later in the login stuff.  This is because it takes too
  330. # long to compute it here.
  331. #
  332. if ( ! $?OS ) then
  333.     set y = `uname -r`
  334.     if ( -e ~/.${hostname}_version && ! -z ~/.${hostname}_version ) then
  335.     set x = ( `cat ~/.${hostname}_version` )
  336.     setenv OS "$y-$x[3]"
  337.     unset x
  338.     else
  339.     setenv OS "$y"
  340.     endif
  341.     unset y
  342. endif
  343.  
  344. if ( $?ENVONLY ) exit
  345.  
  346. ##########################################################################
  347. # CSHRC stuff
  348. #
  349.  
  350. if ( $?cshrc ) then
  351. #----
  352. # Do pretty stuff to prompt string
  353. #   1.    Don't do this if we are not running with an ANSI terminal.
  354. #   2.    If we are the owner of /bin/su, then we must be running in
  355. #    superuser mode and we'll reverse video the prompt.  Otherwise,
  356. #    we'll just use the highlight color.
  357. #
  358.     if ( $ansiterm > 0 ) then
  359.     if ( $ansiterm > 1 ) then
  360.         if ( -o /bin/su ) then
  361.         set prompt="${hostname}:$user [\!] > "
  362.         else
  363.         set prompt="${hostname}:$user [\!] > "
  364.         endif
  365.     else
  366.         set prompt="${hostname}:$user [\!]$prompt "
  367.     endif
  368.     endif
  369.  
  370. #----
  371. # Set csh variables here.  These variables must be set for each shell
  372. # invokation.
  373. #
  374.     set    history    = 100
  375.     set x
  376.     if ( -e ~/developer )    set x = ($x ~/developer)
  377.     if ( -e /usr/local/emacs )    set x = ($x /usr/local/emacs)
  378.     set    cdpath    = (~ $x)
  379.     unset x
  380.     set    filec
  381.     set    fignore    = (.o .a .out \~)
  382.     unset autologout
  383.     set    ignoreeof
  384.     if ( "$CONSOLE" != "true" ) set notify
  385.     unset noclobber
  386.  
  387. #----
  388. # Perform alias definitions.  These must be set for each invokation of
  389. # the csh.
  390. #
  391. # list directories in columns
  392. #
  393.     alias ls    'ls -FC'
  394.     alias ll    'ls -alF \!* | more'
  395.     alias lt    'ls -alFt \!* | more'
  396.     alias mail    Mail -n
  397.     if ( $?DISPLAY ) then
  398.     alias emacs    '/usr/local/bin/emacs \!* &'
  399.     alias epoch    '/usr/local/bin/epoch \!* &'
  400.     alias zmail    'zmail -gui \!* &'
  401.     alias xlock    'xlock -mode random +nolock'
  402.     else
  403.     alias emacs    'emacs -nw'
  404.     alias epoch    'echo "epoch will not run over a modem"'
  405.     endif
  406.     if ( -e ~/scripts ) then
  407.     alias co    '~/scripts/co-script \!*'
  408.     alias col    '~/scripts/col-script -i \!*'
  409.     alias ci    '~/scripts/ci-script \!*'
  410.     endif
  411.     alias unlock "rcs -u \!* ; rm -f \!* >&/dev/null"
  412.  
  413. #----
  414. # Define aliases to do fancy things to the title bar.
  415. #
  416.     if ( $ansiterm == 2 ) then
  417.     alias seticon    'echo "\033P3.y\!*\033\\\c"'
  418.     alias settitle    'echo "\033P1.y\!*\033\\\c"'
  419.  
  420.     if ( "$CONSOLE" == "true" ) then
  421.         alias cu    'cu \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  422.         alias cd    'cd \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  423.         alias rlogin 'rlogin \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  424.         alias rsh    'rsh \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  425.         alias pushd    'pushd \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  426.         alias popd    'popd \!* ; echo "\033P1.yConsole:${cwd}\033\\\c"'
  427.     else
  428.         alias cu    'cu \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  429.         alias cd    'cd \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  430.         alias rlogin 'rlogin \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  431.         alias rsh    'rsh \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  432.         alias pushd    'pushd \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  433.         alias popd    'popd \!* ; echo "\033P1.y${hostname}:${cwd}\033\\\c"'
  434.     endif
  435.     endif
  436.  
  437.     alias etags        etags -t
  438.     alias snoop        '/usr/demos/bin/snoop'
  439.     if ( "${hostname}" == "$home_host" ) then
  440.     alias xrn    'xrn-motif &'
  441.     endif
  442.     alias chkalias    'rsh relay.sgi.com -l guest ypmatch -k \!* aliases'
  443.     alias grepalias    '(rsh relay.sgi.com -l guest ypcat -k aliases) | grep "\!*"'
  444.     alias ping        /usr/etc/ping
  445.     alias bu        'cd $cwd:h'
  446.     alias rcp        'rcp -rv'
  447.     alias xv        'xv -8'
  448.  
  449. endif
  450.  
  451. ##########################################################################
  452. # LOGIN stuff
  453. #
  454.  
  455. if ( $?login ) then
  456. #-----
  457. # Do pretty stuff to window border
  458. #
  459.     if ( "$CONSOLE" == "true" ) then
  460.     echo "\033P1.yConsole at ${hostname}, user: $user\033\\\c"
  461.     else
  462.     if ( $ansiterm == 2 ) then
  463.         if ( $?REMOTEHOST ) then
  464.         echo "\033P1.y${hostname}:`pwd`\033\\\c"
  465.         echo "\033P3.y${hostname}\033\\\c"
  466.         else
  467.         echo "\033P1.y`pwd`\033\\\c"
  468.         echo "\033P3.y${user}\033\\\c"
  469.         endif
  470.     endif
  471.     endif
  472.  
  473. #-----
  474. # Disable functions for f3 and f4 keys.  See bindkey(1).
  475. #
  476.     if ( $ansiterm == 2 ) then
  477.     bindkey -l f3
  478.     bindkey -l f4
  479.     endif
  480.  
  481. endif
  482.  
  483. unset ansiterm
  484. unset home_host
  485.  
  486. ### Local Variables:
  487. ### auto-fill-hook: nil
  488. ### End:
  489.